107 lines
4.4 KiB
Solidity
107 lines
4.4 KiB
Solidity
// SPDX-License-Identifier: MIT
|
|
|
|
pragma solidity ^0.6.2;
|
|
|
|
/**
|
|
* @dev Library used to query support of an interface declared via {IERC165}.
|
|
*
|
|
* Note that these functions return the actual result of the query: they do not
|
|
* `revert` if an interface is not supported. It is up to the caller to decide
|
|
* what to do in these cases.
|
|
*/
|
|
library ERC165Checker {
|
|
// As per the EIP-165 spec, no interface should ever match 0xffffffff
|
|
bytes4 private constant _INTERFACE_ID_INVALID = 0xffffffff;
|
|
|
|
/*
|
|
* bytes4(keccak256('supportsInterface(bytes4)')) == 0x01ffc9a7
|
|
*/
|
|
bytes4 private constant _INTERFACE_ID_ERC165 = 0x01ffc9a7;
|
|
|
|
/**
|
|
* @dev Returns true if `account` supports the {IERC165} interface,
|
|
*/
|
|
function supportsERC165(address account) internal view returns (bool) {
|
|
// Any contract that implements ERC165 must explicitly indicate support of
|
|
// InterfaceId_ERC165 and explicitly indicate non-support of InterfaceId_Invalid
|
|
return _supportsERC165Interface(account, _INTERFACE_ID_ERC165) &&
|
|
!_supportsERC165Interface(account, _INTERFACE_ID_INVALID);
|
|
}
|
|
|
|
/**
|
|
* @dev Returns true if `account` supports the interface defined by
|
|
* `interfaceId`. Support for {IERC165} itself is queried automatically.
|
|
*
|
|
* See {IERC165-supportsInterface}.
|
|
*/
|
|
function supportsInterface(address account, bytes4 interfaceId) internal view returns (bool) {
|
|
// query support of both ERC165 as per the spec and support of _interfaceId
|
|
return supportsERC165(account) &&
|
|
_supportsERC165Interface(account, interfaceId);
|
|
}
|
|
|
|
/**
|
|
* @dev Returns true if `account` supports all the interfaces defined in
|
|
* `interfaceIds`. Support for {IERC165} itself is queried automatically.
|
|
*
|
|
* Batch-querying can lead to gas savings by skipping repeated checks for
|
|
* {IERC165} support.
|
|
*
|
|
* See {IERC165-supportsInterface}.
|
|
*/
|
|
function supportsAllInterfaces(address account, bytes4[] memory interfaceIds) internal view returns (bool) {
|
|
// query support of ERC165 itself
|
|
if (!supportsERC165(account)) {
|
|
return false;
|
|
}
|
|
|
|
// query support of each interface in _interfaceIds
|
|
for (uint256 i = 0; i < interfaceIds.length; i++) {
|
|
if (!_supportsERC165Interface(account, interfaceIds[i])) {
|
|
return false;
|
|
}
|
|
}
|
|
|
|
// all interfaces supported
|
|
return true;
|
|
}
|
|
|
|
/**
|
|
* @notice Query if a contract implements an interface, does not check ERC165 support
|
|
* @param account The address of the contract to query for support of an interface
|
|
* @param interfaceId The interface identifier, as specified in ERC-165
|
|
* @return true if the contract at account indicates support of the interface with
|
|
* identifier interfaceId, false otherwise
|
|
* @dev Assumes that account contains a contract that supports ERC165, otherwise
|
|
* the behavior of this method is undefined. This precondition can be checked
|
|
* with {supportsERC165}.
|
|
* Interface identification is specified in ERC-165.
|
|
*/
|
|
function _supportsERC165Interface(address account, bytes4 interfaceId) private view returns (bool) {
|
|
// success determines whether the staticcall succeeded and result determines
|
|
// whether the contract at account indicates support of _interfaceId
|
|
(bool success, bool result) = _callERC165SupportsInterface(account, interfaceId);
|
|
|
|
return (success && result);
|
|
}
|
|
|
|
/**
|
|
* @notice Calls the function with selector 0x01ffc9a7 (ERC165) and suppresses throw
|
|
* @param account The address of the contract to query for support of an interface
|
|
* @param interfaceId The interface identifier, as specified in ERC-165
|
|
* @return success true if the STATICCALL succeeded, false otherwise
|
|
* @return result true if the STATICCALL succeeded and the contract at account
|
|
* indicates support of the interface with identifier interfaceId, false otherwise
|
|
*/
|
|
function _callERC165SupportsInterface(address account, bytes4 interfaceId)
|
|
private
|
|
view
|
|
returns (bool, bool)
|
|
{
|
|
bytes memory encodedParams = abi.encodeWithSelector(_INTERFACE_ID_ERC165, interfaceId);
|
|
(bool success, bytes memory result) = account.staticcall{ gas: 30000 }(encodedParams);
|
|
if (result.length < 32) return (false, false);
|
|
return (success, abi.decode(result, (bool)));
|
|
}
|
|
}
|