81 lines
2.9 KiB
Solidity
81 lines
2.9 KiB
Solidity
// SPDX-License-Identifier: MIT
|
|
|
|
pragma solidity ^0.6.0;
|
|
|
|
import "./Proxy.sol";
|
|
import "../utils/Address.sol";
|
|
|
|
/**
|
|
* @dev This contract implements an upgradeable proxy. It is upgradeable because calls are delegated to an
|
|
* implementation address that can be changed. This address is stored in storage in the location specified by
|
|
* https://eips.ethereum.org/EIPS/eip-1967[EIP1967], so that it doesn't conflict with the storage layout of the
|
|
* implementation behind the proxy.
|
|
*
|
|
* Upgradeability is only provided internally through {_upgradeTo}. For an externally upgradeable proxy see
|
|
* {TransparentUpgradeableProxy}.
|
|
*/
|
|
contract UpgradeableProxy is Proxy {
|
|
/**
|
|
* @dev Initializes the upgradeable proxy with an initial implementation specified by `_logic`.
|
|
*
|
|
* If `_data` is nonempty, it's used as data in a delegate call to `_logic`. This will typically be an encoded
|
|
* function call, and allows initializating the storage of the proxy like a Solidity constructor.
|
|
*/
|
|
constructor(address _logic, bytes memory _data) public payable {
|
|
assert(_IMPLEMENTATION_SLOT == bytes32(uint256(keccak256("eip1967.proxy.implementation")) - 1));
|
|
_setImplementation(_logic);
|
|
if(_data.length > 0) {
|
|
// solhint-disable-next-line avoid-low-level-calls
|
|
(bool success,) = _logic.delegatecall(_data);
|
|
require(success);
|
|
}
|
|
}
|
|
|
|
/**
|
|
* @dev Emitted when the implementation is upgraded.
|
|
*/
|
|
event Upgraded(address indexed implementation);
|
|
|
|
/**
|
|
* @dev Storage slot with the address of the current implementation.
|
|
* This is the keccak-256 hash of "eip1967.proxy.implementation" subtracted by 1, and is
|
|
* validated in the constructor.
|
|
*/
|
|
bytes32 private constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
|
|
|
|
/**
|
|
* @dev Returns the current implementation address.
|
|
*/
|
|
function _implementation() internal override view returns (address impl) {
|
|
bytes32 slot = _IMPLEMENTATION_SLOT;
|
|
// solhint-disable-next-line no-inline-assembly
|
|
assembly {
|
|
impl := sload(slot)
|
|
}
|
|
}
|
|
|
|
/**
|
|
* @dev Upgrades the proxy to a new implementation.
|
|
*
|
|
* Emits an {Upgraded} event.
|
|
*/
|
|
function _upgradeTo(address newImplementation) internal {
|
|
_setImplementation(newImplementation);
|
|
emit Upgraded(newImplementation);
|
|
}
|
|
|
|
/**
|
|
* @dev Stores a new address in the EIP1967 implementation slot.
|
|
*/
|
|
function _setImplementation(address newImplementation) private {
|
|
require(Address.isContract(newImplementation), "UpgradeableProxy: new implementation is not a contract");
|
|
|
|
bytes32 slot = _IMPLEMENTATION_SLOT;
|
|
|
|
// solhint-disable-next-line no-inline-assembly
|
|
assembly {
|
|
sstore(slot, newImplementation)
|
|
}
|
|
}
|
|
}
|